Finn EversandPeter Tripp
efaf358876
Resolves #26032 This PR changes the highlighting for `and`, `not` and `or` in Lua from `operator` to `keyword.operator`. [VS Code also highlights these as keyword operators](https://github.com/LuaLS/lua.tmbundle/blob/1483add845ebfb3e1e631fe372603e5fed2cdd42/Syntaxes/Lua.plist#L277-L279) and Zed does this for other languages as well, like [Python](https://github.com/zed-industries/zed/blob/813e207514f76ec3f8bc8bbb649deaafa304de9e/crates/languages/src/python/highlights.scm#L221-L229) or [Zig](https://github.com/zed-industries/zed/blob/813e207514f76ec3f8bc8bbb649deaafa304de9e/extensions/zig/languages/zig/highlights.scm#L145-L149). Additionally, in 813e207514f76ec3f8bc8bbb649deaafa304de9e I removed duplicate matches for existing keywords to improve readability and align them to how keywords are generally matched across languages (see [Rust](https://github.com/zed-industries/zed/blob/813e207514f76ec3f8bc8bbb649deaafa304de9e/crates/languages/src/rust/highlights.scm#L79-L119) and [Typescript](https://github.com/zed-industies/zed/blob/813e207514f76ec3f8bc8bbb649deaafa304de9e/crates/languages/src/typescript/highlights.scm#L210-L269) for example). Whilst contributing to the majority of the diff, this does not change any existing highlights. | Before | After | | --- | --- | | <img width="309" alt="old" src="https://github.com/user-attachments/assets/7790817e-4a0d-442b-b176-9a84bcc6f3c4" /> | <img width="309" alt="PR" src="https://github.com/user-attachments/assets/34a57962-938a-4465-9406-288f5c456aa3" /> | Release Notes: - N/A --------- Co-authored-by: Peter Tripp <peter@zed.dev>
149 lines
1.9 KiB
Scheme
149 lines
1.9 KiB
Scheme
;; Keywords
|
|
|
|
[
|
|
"do"
|
|
"else"
|
|
"elseif"
|
|
"end"
|
|
"for"
|
|
"function"
|
|
"goto"
|
|
"if"
|
|
"in"
|
|
"local"
|
|
"repeat"
|
|
"return"
|
|
"then"
|
|
"until"
|
|
"while"
|
|
(break_statement)
|
|
] @keyword
|
|
|
|
;; Operators
|
|
|
|
[
|
|
"and"
|
|
"not"
|
|
"or"
|
|
] @keyword.operator
|
|
|
|
[
|
|
"+"
|
|
"-"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"^"
|
|
"#"
|
|
"=="
|
|
"~="
|
|
"<="
|
|
">="
|
|
"<"
|
|
">"
|
|
"="
|
|
"&"
|
|
"~"
|
|
"|"
|
|
"<<"
|
|
">>"
|
|
"//"
|
|
".."
|
|
] @operator
|
|
|
|
;; Punctuations
|
|
|
|
[
|
|
";"
|
|
":"
|
|
","
|
|
"."
|
|
] @punctuation.delimiter
|
|
|
|
;; Brackets
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
] @punctuation.bracket
|
|
|
|
;; Variables
|
|
|
|
(identifier) @variable
|
|
|
|
((identifier) @variable.special
|
|
(#eq? @variable.special "self"))
|
|
|
|
(variable_list
|
|
attribute: (attribute
|
|
(["<" ">"] @punctuation.bracket
|
|
(identifier) @attribute)))
|
|
|
|
;; Constants
|
|
|
|
((identifier) @constant
|
|
(#match? @constant "^[A-Z][A-Z_0-9]*$"))
|
|
|
|
(vararg_expression) @constant
|
|
|
|
(nil) @constant.builtin
|
|
|
|
[
|
|
(false)
|
|
(true)
|
|
] @boolean
|
|
|
|
;; Tables
|
|
|
|
(field name: (identifier) @property)
|
|
|
|
(dot_index_expression field: (identifier) @property)
|
|
|
|
(table_constructor
|
|
[
|
|
"{"
|
|
"}"
|
|
] @constructor)
|
|
|
|
;; Functions
|
|
|
|
(parameters (identifier) @parameter)
|
|
|
|
(function_call
|
|
name: [
|
|
(identifier) @function
|
|
(dot_index_expression field: (identifier) @function)
|
|
])
|
|
|
|
(function_declaration
|
|
name: [
|
|
(identifier) @function.definition
|
|
(dot_index_expression field: (identifier) @function.definition)
|
|
])
|
|
|
|
(method_index_expression method: (identifier) @function.method)
|
|
|
|
(function_call
|
|
(identifier) @function.builtin
|
|
(#any-of? @function.builtin
|
|
;; built-in functions in Lua 5.1
|
|
"assert" "collectgarbage" "dofile" "error" "getfenv" "getmetatable" "ipairs"
|
|
"load" "loadfile" "loadstring" "module" "next" "pairs" "pcall" "print"
|
|
"rawequal" "rawget" "rawset" "require" "select" "setfenv" "setmetatable"
|
|
"tonumber" "tostring" "type" "unpack" "xpcall"))
|
|
|
|
;; Others
|
|
|
|
(comment) @comment
|
|
|
|
(hash_bang_line) @preproc
|
|
|
|
(number) @number
|
|
|
|
(string) @string
|
|
(escape_sequence) @string.escape
|