Piotr Osiewicz
0f584cb353
- Moves languages module from `zed` into a separate crate. That way we have less of a long pole at the end of compilation. - Removes moot dependencies on editor/picker. This is totally harmless and might help in the future if we decide to decouple picker from editor. Before: ``` Number of crates that depend on 'picker' but not on 'editor': 1 Total number of crates that depend on 'picker': 13 Total number of crates that depend on 'editor': 30 ``` After: ``` Number of crates that depend on 'picker' but not on 'editor': 5 Total number of crates that depend on 'picker': 12 Total number of crates that depend on 'editor': 26 ``` The more crates depend on just picker but not editor, the better in that case. Release Notes: - N/A
49 lines
940 B
Scheme
49 lines
940 B
Scheme
(module_type_definition
|
|
"module" @context
|
|
"type" @context
|
|
name: (_) @name) @item
|
|
|
|
(module_definition
|
|
"module" @context
|
|
(module_binding name: (_) @name)) @item
|
|
|
|
(type_definition
|
|
"type" @context
|
|
(type_binding name: (_) @name)) @item
|
|
|
|
(class_definition
|
|
"class" @context
|
|
(class_binding
|
|
"virtual"? @context
|
|
name: (_) @name)) @item
|
|
|
|
(class_type_definition
|
|
"class" @context
|
|
"type" @context
|
|
(class_type_binding
|
|
"virtual"? @context
|
|
name: (_) @name)) @item
|
|
|
|
(instance_variable_definition
|
|
"val" @context
|
|
"method"? @context
|
|
name: (_) @name) @item
|
|
|
|
(method_specification
|
|
"method" @context
|
|
"virtual"? @context
|
|
(method_name) @name) @item
|
|
|
|
(value_specification
|
|
"val" @context
|
|
(value_name) @name) @item
|
|
|
|
(external
|
|
"external" @context
|
|
(value_name) @name) @item
|
|
|
|
(exception_definition
|
|
"exception" @context
|
|
(constructor_declaration
|
|
(constructor_name) @name)) @item
|