Joseph T. Lyons
f6eaa8b00f
I saved the `file_types.json` file and got a diff because it had some trailing whitespace. I ran [`lineman`](https://github.com/JosephTLyons/lineman) on the codebase. I've done this before, but this time, I've added in the following settings to our `.zed` local settings, to make sure every future save respects our desire to have consistent whitespace formatting. ```json "remove_trailing_whitespace_on_save": true, "ensure_final_newline_on_save": true ``` Release Notes: - N/A
60 lines
1.1 KiB
Scheme
60 lines
1.1 KiB
Scheme
(_structure_item/value_definition
|
|
"let" @context
|
|
(let_binding
|
|
pattern: (_) @name)) @item
|
|
|
|
(_structure_item/exception_definition
|
|
"exception" @context
|
|
(constructor_declaration
|
|
(constructor_name) @name)) @item
|
|
|
|
(_structure_item/module_definition
|
|
"module" @context
|
|
(module_binding
|
|
name: (module_name) @name)) @item
|
|
|
|
(module_type_definition
|
|
"module" @context
|
|
"type" @context
|
|
name: (_) @name) @item
|
|
|
|
(type_definition
|
|
"type" @context
|
|
(type_binding name: (_) @name)) @item
|
|
|
|
(value_specification
|
|
"val" @context
|
|
(value_name) @name) @item
|
|
|
|
(class_definition
|
|
"class" @context
|
|
(class_binding
|
|
"virtual"? @context
|
|
name: (_) @name)) @item
|
|
|
|
(class_type_definition
|
|
"class" @context
|
|
"type" @context
|
|
(class_type_binding
|
|
"virtual"? @context
|
|
name: (_) @name)) @item
|
|
|
|
(instance_variable_definition
|
|
"val" @context
|
|
"method"? @context
|
|
name: (_) @name) @item
|
|
|
|
(method_specification
|
|
"method" @context
|
|
"virtual"? @context
|
|
(method_name) @name) @item
|
|
|
|
(method_definition
|
|
"method" @context
|
|
"virtual"? @context
|
|
name: (_) @name) @item
|
|
|
|
(external
|
|
"external" @context
|
|
(value_name) @name) @item
|